// ******************************
//  Crazy Ranks by Venjax V1.1
//      For Counter Strike: Source
//
// * Description:
//      Players are assigned ranks based on score.
//      Players score points based on how they killed their enemies.
//
// * Install instructions:
//       http://forums.mattie.info/cs/forums/
//
//
// * Requirements:
//      EventScripts
//      
// ******************************
 
 
// ******************************
//   CONFIGURABLE SETTINGS
// ******************************
 
block config
{
// ******************************
// Customize score per hitgroup.
// ******************************
 
  es_xsetinfo crazyadvert 1   // Set to 1 to turn on Round_Start Advertisment of CrazyRanks
 
  es_xsetinfo headscore 100   //Score for headshots AND knife kills
  es_xsetinfo pelvisscore 75  //Pelvis/lower torso kills
  es_xsetinfo bodyscore 50    //Upper body kills
  es_xsetinfo armscore 25     //Arm kills
  es_xsetinfo legscore 20     //Leg kills
  es_xsetinfo punishscore 100    //Score to DEDUCT for TeamKills and Suicides
 
 
// ******************************
//   RANK TITLES AND VALUES
// ******************************
 
  es_keycreate crazyranks 0
  es_keysetvalue crazyranks 0 rank "Crazy Fodder"
  es_keycreate crazyranks 500
  es_keysetvalue crazyranks 500 rank "Crazy Newb"
  es_keycreate crazyranks 1000
  es_keysetvalue crazyranks 1000 rank "Crazy Scout"
  es_keycreate crazyranks 2000
  es_keysetvalue crazyranks 2000 rank "Crazy Marksman"
  es_keycreate crazyranks 5000
  es_keysetvalue crazyranks 5000 rank "Crazy Sniper"
  es_keycreate crazyranks 8000
  es_keysetvalue crazyranks 8000 rank "Crazy Sharpshooter"
  es_keycreate crazyranks 100000
  es_keysetvalue crazyranks 100000 rank "Needs a crazy Life!"
 
 
// Copy and paste to add more rank titles Add as many as you'd like.
// BUT MAKE SURE THEY ARE IN ORDER FROM LOWEST TO HIGHEST VALUES.
//
// BOTH LINES ARE REQUIRED PER RANK TITLE.
//
//  es_keycreate crazyranks 
//  es_keysetvalue crazyranks  ""
 
}
 
 
// ******************************
//  END OF CONFIGURABLE SETTINGS
// ******************************
 
// ******************************
//  DO NOT EDIT BELOW THIS LINE!
// ******************************
 
 
 
block load
{
  es_keygroupdelete crazyranks
  es_keygroupcreate crazyranks 
  es_keygroupdelete crazyscore
  es_keygroupload crazyscore |crazyranks
  es_xsetinfo ven_crazyrank "V1.1"
  es_xsetinfo exkey 0
  es_xsetinfo myscore 0
  es_xsetinfo myrank 0
  es_xsetinfo addscore 0
  es_xsetinfo checker 0
  es_xsetinfo newrank 0
  es_makepublic ven_crazyrank
  es_doblock crazyranks/config
}
 
event player_activate
{
  es_exists exkey key crazyscore event_var(es_steamid)
  if (server_var(exkey) equalto 0) do
  {
    es_keycreate crazyscore event_var(es_steamid)
    es_keysetvalue crazyscore event_var(es_steamid) rank "0"
    es_keysetvalue crazyscore event_var(es_steamid) score "0"
  }
}
 
event round_start
{
  if (server_var(crazyadvert) equalto 1) do
  {
    es_msg #multi #default [CrazyRanks]#green Type #lightgreen!crazyrank#green to check your score and rank.
    es_keygroupsave crazyscore |crazyranks
  }
}
 
event player_say
{
if (event_var(text) equalto "!crazyrank") do
  {
    es_keygetvalue myrank crazyscore event_var(es_steamid) rank
    es_keygetvalue myscore crazyscore event_var(es_steamid) score
    es_tell event_var(userid) #multi #default [CrazyRanks]#green event_var(es_username) is ranked#lightgreen server_var(myrank)#green with the score of#lightgreen server_var(myscore)#green points!
  }
}
 
event player_hurt
{
  if (event_var(hitgroup) < 2) do
  {
    es_setinfo addscore server_var(headscore)
  }
    if (event_var(hitgroup) equalto 2) do
  {
    es_setinfo addscore server_var(bodyscore)
  }
    if (event_var(hitgroup) equalto 3) do
  {
    es_setinfo addscore server_var(pelvisscore)
  }
    if (event_var(hitgroup) equalto 4) do
  {
    es_setinfo addscore server_var(armscore)
  }
    if (event_var(hitgroup) equalto 5) do
  {
    es_setinfo addscore server_var(armscore)
  }
    if (event_var(hitgroup)  > 5) do
  {
    es_setinfo addscore server_var(legscore)
  }
}
 
event player_death
{
 
  if (event_var(es_userteam) notequalto event_var(es_attackerteam)) do
  {
    if (event_var(es_attackerteam) equalto 0) do
    {
      es_keygetvalue myrank crazyscore event_var(es_steamid) rank
      es_keygetvalue myscore crazyscore event_var(es_steamid) score
      es_math myscore - server_var(punishscore)
 
      es_foreachkey checker in crazyranks "es_xdoblock crazyranks/checker"
 
      if (server_var(newrank) notequalto server_var(myrank)) do
      {
        es_msg #multi #default[CrazyRank]#green event_var(es_username) has just been demoted to#lightgreen server_var(newrank)#green for committing suicide!
        es_setinfo myrank server_var(newrank)
      }
    es_keysetvalue crazyscore event_var(es_steamid) rank server_var(myrank) 
    es_keysetvalue crazyscore event_var(es_steamid) score server_var(myscore)
    }
    else do
    {
      es_keygetvalue myrank crazyscore event_var(es_attackersteamid) rank
      es_keygetvalue myscore crazyscore event_var(es_attackersteamid) score
      es_math myscore + server_var(addscore)
 
      es_foreachkey checker in crazyranks "es_xdoblock crazyranks/checker"
 
      if (server_var(newrank) notequalto server_var(myrank)) do
      {
        es_msg #multi #default[CrazyRank]#green event_var(es_attackername) has just been promoted to#lightgreen server_var(newrank)#green!
        es_setinfo myrank server_var(newrank)
      }
    es_keysetvalue crazyscore event_var(es_attackersteamid) rank server_var(myrank) 
    es_keysetvalue crazyscore event_var(es_attackersteamid) score server_var(myscore)
    }
  }
  else do
  {
    es_keygetvalue myrank crazyscore event_var(es_attackersteamid) rank
    es_keygetvalue myscore crazyscore event_var(es_attackersteamid) score
    es_math myscore - server_var(punishscore)
 
    es_foreachkey checker in crazyranks "es_xdoblock crazyranks/checker"
 
    if (server_var(newrank) notequalto server_var(myrank)) do
    {
      es_msg #multi #default[CrazyRank]#green event_var(es_attackername) has just been demoted to#lightgreen server_var(newrank)#green for teamkilling!
      es_setinfo myrank server_var(newrank)
    }
  es_keysetvalue crazyscore event_var(es_attackersteamid) rank server_var(myrank) 
  es_keysetvalue crazyscore event_var(es_attackersteamid) score server_var(myscore)
  }
}
 
 
block checker
{
  if (server_var(myscore) > server_var(checker)) do
  {
    es_keygetvalue newrank crazyranks server_var(checker) rank   
  }
}
 
block unload
{
    es_keygroupsave crazyscore |crazyranks
    es_keygroupdelete crazyscore
    es_keygroupdelete crazyranks
}