/////////////////////////////////////////
// Script Author: [HKR] Chief         //
// Member, [HKR] Clan                 //
// Email: HKR.CHIEF@GMAIL.COM         //
//                                    //
// The main Popup menu code was       ////////////////////////////
// borrowed from Cookie's Gunmenu                               //
// http://addons.eventscripts.com/addons/view/cookies_gunmenu   //
//                                                              //
//////////////////////////////////////////////////////////////////
//
// Last Modified Date: 02/23/08
//
//
// *****************************************************************************
// Script Description: This script is a buy script. It stores all weapon values in
// a keygroup named weapons. You can assign cost of weapons, trade-in value of
// weapons, and you can restrict weapons from purchase. When users use this system
// to buy weapons, it will automatically trade in their current weapon (if any) from
// that slot, depending on what type of weapon they are buying, and give them
// a discount off their new weapon. All prices are adjustable in weapon table.
// *****************************************************************************
//
//
// *****************************************************************************
// Module Description: During loading, Initiates Variables to be used.
// and sets up menu system.
// *****************************************************************************

block load
{
	es_xset wep_choice 0
	es_xset users_cash 0
	es_xset wep_cost 0
	es_xset wep_restrict 0
	es_xset wep_slot 0
	es_xset wep_tradein 0
	es_xset users_weapon 0
	es_xset index_var 0
	es_xsetinfo HKR_Black_Market_Weapons "Version 1.0"
	es_makepublic HKR_Black_Market_Weapons


	popup create guns1
	popup addline guns1 "HKR Black Market Weapons"
	popup addline guns1 "_____________________"
	popup addline guns1 " "
	popup addline guns1 "->1. Pistols"
	popup addline guns1 "->2. Shotguns"
	popup addline guns1 "->3. Sub-Machine Guns"
	popup addline guns1 "->4. Rifles"
	popup addline guns1 "->5. Machine Guns"
	popup addline guns1 "->6. Other"
	popup addline guns1 " "
	popup addline guns1 "_____________________"
	popup addline guns1 "->9. Strip My Weapons"
	popup addline guns1 "0. Exit"
	popup menuselect guns1 weps/guns1select
	popup timeout guns1 send 30

	popup create pistols
	popup addline pistols "HKR Black Market Weapons"
	popup addline pistols "_____________________"
	popup addline pistols " "
	popup addline pistols "->1. Glock"
	popup addline pistols "->2. USP"
	popup addline pistols "->3. P228"
	popup addline pistols "->4. Deagle"
	popup addline pistols "->5. Five Seven"
	popup addline pistols "->6. Elite"
	popup addline pistols " "
	popup addline pistols "_____________________"
	popup addline pistols "->9. Back"
	popup addline pistols "0. Exit"
	popup menuselect pistols weps/pistolselect
	popup timeout pistols send 30

	popup create shotguns
	popup addline shotguns "HKR Black Market Weapons"
	popup addline shotguns "_____________________"
	popup addline shotguns " "
	popup addline shotguns "->1. M3"
	popup addline shotguns "->2. XM1014"
	popup addline shotguns " "
	popup addline shotguns "_____________________"
	popup addline shotguns "->9. Back"
	popup addline shotguns "0. Exit"
	popup menuselect shotguns weps/shotgunselect
	popup timeout shotguns send 30

	popup create submach
	popup addline submach "HKR Black Market Weapons"
	popup addline submach "_____________________"
	popup addline submach " "
	popup addline submach "->1. TMP"
	popup addline submach "->2. Mac10"
	popup addline submach "->3. MP5Navy"
	popup addline submach "->4. UMP45"
	popup addline submach "->5. P90"
	popup addline submach " "
	popup addline submach "_____________________"
	popup addline submach "->9. Back"
	popup addline submach "0. Exit"
	popup menuselect submach weps/submachselect
	popup timeout submach send 30

	popup create rifle
	popup addline rifle "HKR Black Market Weapons"
	popup addline rifle "_____________________"
	popup addline rifle " "
	popup addline rifle "->1. Famas"
	popup addline rifle "->2. Galil"
	popup addline rifle "->3. Ak47"
	popup addline rifle "->4. M4A1"
	popup addline rifle "->5. AUG"
	popup addline rifle " "
	popup addline rifle "_____________________"
	popup addline rifle "->8. Sniper Rifles"
	popup addline rifle "->9. Back"
	popup addline rifle "0. Exit"
	popup timeout rifle send 30
	popup menuselect rifle weps/rifleselect

	popup create sniper
	popup addline sniper "HKR Black Market Weapons"
	popup addline sniper "_____________________"
	popup addline sniper " "
	popup addline sniper "->1. Scout"
	popup addline sniper "->2. SG550"
	popup addline sniper "->3. G3SG1"
	popup addline sniper "->4. AWP"
	popup addline sniper " "
	popup addline sniper "_____________________"
	popup addline sniper "->9. Back"
	popup addline sniper "0. Evit"
	popup menuselect sniper weps/sniperselect
	popup timeout sniper send 30

	popup create mach
	popup addline mach "HKR Black Market Weapons"
	popup addline mach "_____________________"
	popup addline mach " "
	popup addline mach "->1. M249"
	popup addline mach " "
	popup addline mach "_____________________"
	popup addline mach "->9. Back"
	popup addline mach "0. Exit"
	popup menuselect mach weps/machselect
	popup timeout mach send 30

	popup create other
	popup addline other "HKR Black Market Weapons"
	popup addline other "_____________________"
	popup addline other " "
	popup addline other "->1. HE Grenade"
	popup addline other "->2. Flashbang"
	popup addline other "->3. Smoke Grenade"
	popup addline other "->4. Night Vision"
	popup addline other " "
	popup addline other " "
	popup addline other "_____________________"
	popup addline other "->9. Back"
	popup addline other "0. Exit"
	popup menuselect other weps/otherselect
	popup timeout other send 30


}

// *****************************************************************************
// Module Description: When unloading script, clears Variables and removes menus.
// *****************************************************************************
block unload
{
	popup delete guns1
	popup delete pistols
	popup delete shotguns
	popup delete submach
	popup delete rifle
	popup delete sniper
	popup delete mach
	popup delete other
	es_xset wep_choice 0
	es_xset users_cash 0
	es_xset wep_cost 0
	es_xset wep_restrict 0
	es_xset wep_slot 0
	es_xset wep_tradein 0
	es_xset users_weapon 0
	es_xset index_var 0
}

// *****************************************************************************
// Module Description: This simply calls the menu to the user that called it.
// *****************************************************************************

block send
{
	es popup send guns1 event_var(userid)
}

// *****************************************************************************
// Module Description: At player death, if human, it will remove the menu from
// players screen. Why buy if you're dead?
// *****************************************************************************

event player_death
{
	if(event_var(es_steamid) != BOT) do
	{
		es popup unsendname guns1 event_var(userid)
		es popup unsendname pistols event_var(userid)
		es popup unsendname shotguns event_var(userid)
		es popup unsendname submach event_var(userid)
		es popup unsendname rifle event_var(userid)
		es popup unsendname sniper event_var(userid)
		es popup unsendname mach event_var(userid)
		es popup unsendname other event_var(userid)
	}
}

// *****************************************************************************
// Module Description: At round start, it makes sure nobody is starting with a menu up.
// *****************************************************************************

event round_start
{
	es_keygroupload weapons
	es popup unsendname guns1 #human
	es popup unsendname pistols #human
	es popup unsendname shotguns #human
	es popup unsendname submach #human
	es popup unsendname rifle #human
	es popup unsendname sniper #human
	es popup unsendname mach #human
	es popup unsendname other #human
	es_msg #multi #green [HKR Black Market Weapons] #default Type #lightgreen @b #default to purchase weapons!
	es_msg #multi #default Purchase weapons #green Anytime, Anyplace!
}

// *****************************************************************************
// Module Description: This catches the keywords to open the menu. Only works
// if you're alive.
// *****************************************************************************

event player_say
{
	if(event_var(es_userdead) == 0) do
	{
		if(event_var(text) = @b) do
		{
			es_doblock weps/send
		}
		if(event_var(text) = @buy) do
		{
			es_xdoblock weps/send
		}
	}
}

// *****************************************************************************
// Module Description: The following blocks are for each menu. The first one is the main menu.
// *****************************************************************************

block guns1select
{
	if (server_var(_popup_choice) == 1) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send pistols event_var(userid)
	}
	if (server_var(_popup_choice) == 2) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send shotguns event_var(userid)
	}
	if (server_var(_popup_choice) == 3) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send submach event_var(userid)
	}
	if (server_var(_popup_choice) == 4) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send rifle event_var(userid)
	}
	if (server_var(_popup_choice) == 5) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send mach event_var(userid)
	}
	if (server_var(_popup_choice) == 6) do
	{
		es popup unsend guns1 event_var(userid)
		es popup send other event_var(userid)
	}
	if (server_var(_popup_choice) == 9) do
	{
		es est_stripplayer event_var(userid) 0
		es_give event_var(userid) weapon_knife
		es popup send guns1 event_var(userid)
	}
}

block pistolselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_set wep_choice weapon_glock
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_set wep_choice weapon_usp
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 3) do
	{
		es_set wep_choice weapon_p228
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 4) do
	{
		es_set wep_choice weapon_deagle
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 5) do
	{
		es_set wep_choice weapon_fiveseven
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 6) do
	{
		es_set wep_choice weapon_elite
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend pistols event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

block shotgunselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_set wep_choice weapon_m3
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_set wep_choice weapon_xm1014
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend shotguns event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

block submachselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_set wep_choice weapon_tmp
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_set wep_choice weapon_mac10
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 3) do
	{
		es_set wep_choice weapon_mp5navy
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 4) do
	{
		es_set wep_choice weapon_ump45
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 5) do
	{
		es_set wep_choice weapon_p90
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend submach event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

block rifleselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_xset wep_choice weapon_famas
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_xset wep_choice weapon_galil
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 3) do
	{
		es_xset wep_choice weapon_ak47
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 4) do
	{
		es_xset wep_choice weapon_m4a1
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 5) do
	{
		es_xset wep_choice weapon_aug
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 8) do
	{
		es popup unsend rifle event_var(userid)
		es popup send sniper event_var(userid)
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend rifle event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

block sniperselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_xset wep_choice weapon_scout
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_xset wep_choice weapon_sg550
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 3) do
	{
		es_xset wep_choice weapon_g3sg1
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 4) do
	{
		es_xset wep_choice weapon_awp
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend sniper event_var(userid)
		es popup send rifle event_var(userid)
	}
}

block machselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_xset wep_choice weapon_m249
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 5) do
	{
		es popup unsend mach event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

block otherselect
{
	if (server_var(_popup_choice) == 1) do
	{
		es_xset wep_choice weapon_hegrenade
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 2) do
	{
		es_xset wep_choice weapon_flashbang
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 3) do
	{
		es_xset wep_choice weapon_smokegrenade
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 4) do
	{
		es_xset wep_choice weapon_nightvision
		es_doblock weps/wep_selection
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup unsend other event_var(userid)
		es popup send guns1 event_var(userid)
	}
}

// *****************************************************************************
// Module Description: This block checks to see if the item is restriced.
// If not restricted, it then checks to see if it's a primary/secondary weapon,
// or if it's another item like a grenade.
// *****************************************************************************

block wep_selection
{
	es_keygetvalue wep_restrict Weapons server_var(wep_choice) restricted
	if(server_var(wep_restrict) == 1) do
	{
		es_tell event_var(userid) #lightblue That item is Restricted!
		es popup send guns1 event_var(userid)
	}
	else do
	{
		es_xset users_cash 0
		es_getmoney users_cash event_var(userid)
		es_keygetvalue wep_slot weapons server_var(wep_choice) slot
		if(server_var(wep_slot) > 2) do
		{
			es_doblock weps/other_item_buy
		}
		else do
		{
			es_doblock weps/weapon_buy
		}

	}
}

// *****************************************************************************
// Module Description: It calls this block if the item selected is not a primary or
// secondary weapon. Things such as hand grenades and nightvision. No trade in on these items.
// *****************************************************************************

block other_item_buy
{
	es_keygetvalue wep_cost weapons server_var(wep_choice) price
	if(server_var(wep_cost) <= server_var(users_cash)) do
	{
		es_math users_cash subtract server_var(wep_cost)
		es playerset cash event_var(userid) server_var(users_cash)
		es_give event_var(userid) server_var(wep_choice)
		es popup send guns1 event_var(userid)
	}
	else do
	{
		es_tell event_var(userid) #lightblue Sorry, insufficient funds.
		es popup send guns1 event_var(userid)
	}
}

// *****************************************************************************
// Module Description: This block is called if it's a weapon purchase. It figures
// up trade in value of person's current weapon for that slot, then calculates if
// he has enough money, with trade in for the purchase. If so, it takes his old
// weapon, and gives him the new one.
// *****************************************************************************

block weapon_buy
{
	//is it a primary weapon he's buying or a secondary?
	if(server_var(wep_slot) == 1) do
	{
		es playerget primary users_weapon event_var(userid)
	}
	else do
	{
		es playerget secondary users_weapon event_var(userid)
	}
	//what if he doesn't alreay have a weapon for that slot?
	if(server_var(users_weapon) == 0) do
	{
		//then just check pricing and give it to him if he has enough money.
		es_keygetvalue wep_cost weapons server_var(wep_choice) price
		es_math users_cash subtract server_var(wep_cost)
		if(server_var(wep_cost) <= server_var(users_cash)) do
		{
			es playerset cash event_var(userid) server_var(users_cash)
			es_delayed .1 es_give event_var(userid) server_var(wep_choice)
			es popup send guns1 event_var(userid)
		}
		else do
		{
			es_tell event_var(userid) #lightblue Sorry, insufficient funds.
			es popup send guns1 event_var(userid)
		}
	}
	else do
	//here's where it takes his current weapon for tradein value before making the purchase
	{
		es_keygetvalue wep_cost weapons server_var(wep_choice) price
		es_keygetvalue wep_tradein weapons server_var(users_weapon) tradein
		es_tell event_var(userid) #green Your trade in value on your server_var(users_weapon) is server_var(wep_tradein)
		es_math wep_cost subtract server_var(wep_tradein)
		es_math users_cash subtract server_var(wep_cost)
		if(server_var(wep_cost) <= server_var(users_cash)) do
		{
			//if he has enough money with trade in value, make the purchase.
			es playerget weaponindex index_var event_var(userid) server_var(users_weapon)
			es_remove server_var(index_var)
			es playerset cash event_var(userid) server_var(users_cash)
			es_delayed .1 es_give event_var(userid) server_var(wep_choice)
			es popup send guns1 event_var(userid)
		}
		else do
		{
			es_tell event_var(userid) #lightblue Sorry, insufficient funds.
			es popup send guns1 event_var(userid)
		}
	}
}