//-------------------------------------------------------------------------------------
// Weapons Unlimited v 2.0
// by Don Lafferty
// 1/21/2007
//
// Description: 
//   This EventScripts addon will allow all players
//   to choose any weapon in the arsenal at any time.
//   Unlike beta version this version allows you to
//   keep all your weapons.
//
// Features: 
//   Can be restricted to certain Steam IDs.
//   Use ES Tools or corelib's playergetset.
//
// Requirements:
//   Eventscripts v1.2.1
//   ES Tools .416d OR corelib's playergetset.  Only need 1 or the other.
//   GodJonez Popup
//
// Installation:
//   Put this file into a directory as follows
//   cstrike/addons/eventscripts/unlimitedweapons/
//
// Notes:
//   Invoke the menu by typing !wu in the console or player chat or
//   binding a key to !wu.
//
block load
{
// Set this to 1 to restrict users to only Steam IDs in the list
	es_xsetinfo restrictuser 0

// Enter the allowed Steam IDS if you are restricting above
	es_xsetinfo allowedsteamids "STEAM_0:1:7788192-STEAM_0:0:8261521"

// Set this to 1 if you are using ES Tools or 0 if you are using
// corelib's playergetset
	es_xsetinfo use_es_tools 0

	es_doblock weaponsunlimited/createpopup
	es_xsetinfo haswepc4 0
	es_xsetinfo haswephe 0
	es_xsetinfo haswepfb 0
	es_xsetinfo haswepsg 0
	es_xsetinfo weaponpri 0
	es_xsetinfo weaponsec 0
	es_xsetinfo eswu_ver 2.0
	es_makepublic eswu_ver
}

block unload
{
	popup delete wumain
	popup delete wuprimary1
	popup delete wuprimary2
	popup delete wuprimary3
	popup delete wusecondary
	popup delete wugrenades

}

event round_start
{
  es_msg #multi #default[Weapons Unlimited] #greenType #lightgreen!wu #greento bring up the menu!
}


event es_client_command
{
	if (event_var(command) == !wu) do
	{
		if (server_var(restrictuser) == 1) do
		{
			if (event_var(es_steamid) in server_var(allowedsteamids)) do
			{
				es popup send wumain event_var(userid)
			}
			else do
			{
				es_tell event_var(userid) #multi #greenYou do not have access to Weapons Unlimited
			}
		}
		else do
		{
			es popup send wumain event_var(userid)
		}
	}
}

event player_say
{
	if (event_var(text) == !wu) do
	{
		if (server_var(restrictuser) == 1) do
		{
			if (event_var(es_steamid) in server_var(allowedsteamids)) do
			{
				es popup send wumain event_var(userid)
			}
			else do
			{
				es_tell event_var(userid) #multi #greenYou do not have access to Weapons Unlimited
			}
		}
		else do
		{
			es popup send wumain event_var(userid)
		}
	}
}

block selecttype
{
	if (server_var(_popup_choice) == 1) then popup send wuprimary1 server_var(_popup_userid)
	if (server_var(_popup_choice) == 2) then popup send wusecondary server_var(_popup_userid)
	if (server_var(_popup_choice) == 3) then popup send wugrenades server_var(_popup_userid)
}

block selectgrenade
{
	if (server_var(_popup_choice) == 1) do
	{
		if (server_var(use_es_tools) == 0) do
		{
			es playerget he haswephe server_var(_popup_userid)
		}
		else do
		{
			es est_gethe haswephe server_var(_popup_userid)
		}

		if (server_var(haswephe) == 0) do
		{
			es_give server_var(_popup_userid) weapon_hegrenade
		}
		else do
		{
			es_tell server_var(_popup_userid) #multi #greenYou already have an HE Grenade!
		}
	}
	if (server_var(_popup_choice) == 2) do
	{
		if (server_var(use_es_tools) == 0) do
		{
			es playerget sg haswepsg server_var(_popup_userid)
		}
		else do
		{
			es est_getsg haswepsg server_var(_popup_userid)
		}
		if (server_var(haswepsg) == 0) do
		{
			es_give server_var(_popup_userid) weapon_smokegrenade
		}
		else do
		{
			es_tell server_var(_popup_userid) #multi #greenYou already have a Smoke Grenade!
		}
	}
	if (server_var(_popup_choice) == 3) do
	{
		if (server_var(use_es_tools) == 0) do
		{
			es playerget fb haswepfb server_var(_popup_userid)
		}
		else do
		{
			es est_getfb haswepfb server_var(_popup_userid)
		}
		if (server_var(haswepfb) < 2) do
		{
			es_give server_var(_popup_userid) weapon_flashbang
		}
		else do
		{
			es_tell server_var(_popup_userid) #multi #greenYou already have 2 Flashbang Grenades!
		}
	}
}

block selectpri1
{
	if (server_var(_popup_choice) < 9) do
	{
		es_setinfo prisec pri
		es_doblock weaponsunlimited/pregive
		if (server_var(_popup_choice) == 1) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_awp
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.005" 30
		}
		if (server_var(_popup_choice) == 2) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_scout
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.002" 90
		}
		if (server_var(_popup_choice) == 3) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_aug
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.002" 120
		}
		if (server_var(_popup_choice) == 4) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_mac10
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.008" 120
		}
		if (server_var(_popup_choice) == 5) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_tmp
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.006" 120
		}
		if (server_var(_popup_choice) == 6) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_mp5navy
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.006" 120
		}
		if (server_var(_popup_choice) == 7) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_ump45
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.008" 120
		}
		if (server_var(_popup_choice) == 8) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_P90
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.010" 120
		}
		es_doblock weaponsunlimited/postgive
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup send wuprimary2 server_var(_popup_userid)
	}
}

block selectpri2
{
	if (server_var(_popup_choice) < 8) do
	{
		es_setinfo prisec pri
		es_doblock weaponsunlimited/pregive
		if (server_var(_popup_choice) == 1) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_galil
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.003" 120
		}
		if (server_var(_popup_choice) == 2) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_famas
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.003" 120
		}
		if (server_var(_popup_choice) == 3) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_ak47
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.002" 120
		}
		if (server_var(_popup_choice) == 4) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_sg552
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.003" 120
		}
		if (server_var(_popup_choice) == 5) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_sg550
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.003" 120
		}
		if (server_var(_popup_choice) == 6) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_g3sg1
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.002" 120
		}
		if (server_var(_popup_choice) == 7) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_m249
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.004" 120
		}
		es_doblock weaponsunlimited/postgive
	}
	if (server_var(_popup_choice) == 8) do
	{
		es popup send wuprimary1 server_var(_popup_userid)
	}
	if (server_var(_popup_choice) == 9) do
	{
		es popup send wuprimary3 server_var(_popup_userid)
	}
}

block selectpri3
{
	if (server_var(_popup_choice) < 4) do
	{
		es_setinfo prisec pri
		es_doblock weaponsunlimited/pregive
		if (server_var(_popup_choice) == 1) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_m4a1
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.003" 90
		}
		if (server_var(_popup_choice) == 2) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_m3
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.007" 25
		}
		if (server_var(_popup_choice) == 3) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_xm1014
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.007" 40
		}
		es_doblock weaponsunlimited/postgive
	}
	if (server_var(_popup_choice) == 8) do
	{
		es popup send wuprimary2 server_var(_popup_userid)
	}
}

block selectsec
{
	if (server_var(_popup_choice) < 7) do
	{
		es_setinfo prisec sec
		es_doblock weaponsunlimited/pregive
		if (server_var(_popup_choice) == 1) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_glock
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.006" 60
		}
		if (server_var(_popup_choice) == 2) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_usp
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.008" 60
		}
		if (server_var(_popup_choice) == 3) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_p228
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.009" 60
		}
		if (server_var(_popup_choice) == 4) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_deagle
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.001" 60
		}
		if (server_var(_popup_choice) == 5) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_elite
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.006" 60
		}
		if (server_var(_popup_choice) == 6) do
		{
			es_delayed .1 es_give server_var(_popup_userid) weapon_fiveseven
			es_delayed .1 es_setplayerprop server_var(_popup_userid) "CBasePlayer.localdata.m_iAmmo.010" 60
		}
		es_doblock weaponsunlimited/postgive
	}
}

block pregive
{
	if (server_var(use_es_tools) == 0) do
	{
		es playerget c4 haswepc4 server_var(_popup_userid)
		es playerget he haswephe server_var(_popup_userid)
		es playerget sg haswepsg server_var(_popup_userid)
		es playerget fb haswepfb server_var(_popup_userid)
		es playerget primary weaponpri server_var(_popup_userid)
		es playerget secondary weaponsec server_var(_popup_userid)
	}
	else do
	{
		es est_isbomber haswepc4 server_var(_popup_userid)
		es est_gethe haswephe server_var(_popup_userid)
		es est_getsg haswepsg server_var(_popup_userid)
		es est_getfb haswepfb server_var(_popup_userid)
		es est_getprimary weaponpri server_var(_popup_userid)
		es est_getsecondary weaponsec server_var(_popup_userid)
	}
	es_give server_var(_popup_userid) player_weaponstrip
	es_fire server_var(_popup_userid) player_weaponstrip strip
}

block postgive
{
	es_delayed .3 es_give server_var(_popup_userid) weapon_knife
	if (server_var(haswephe) == 1) then es_delayed .3 es_give server_var(_popup_userid) weapon_hegrenade
	if (server_var(haswepsg) == 1) then es_delayed .3 es_give server_var(_popup_userid) weapon_smokegrenade
	if (server_var(haswepc4) == 1) then es_delayed .3 es_give server_var(_popup_userid) weapon_c4
	if (server_var(haswepfb) > 0) then es_delayed .3 es_give server_var(_popup_userid) weapon_flashbang
	if (server_var(haswepfb) == 2) then es_delayed .4 es_give server_var(_popup_userid) weapon_flashbang
	if (server_var(prisec) = pri) do
	{
		if (server_var(weaponsec) != 0) then es_delayed .3  es_give server_var(_popup_userid) server_var(weaponsec)
	}
	if (server_var(prisec) = sec) do
	{
		if (server_var(weaponpri) != 0) then es_delayed .3  es_give server_var(_popup_userid) server_var(weaponpri)
	}
}

block createpopup
{
	popup create wumain
	popup addline wumain "Select a Weapon Type"
	popup addline wumain "1. Primary Weapon"
	popup addline wumain "2. Secondary Weapon"
	popup addline wumain "3. Grenade"
	popup addline wumain "0. Quit"
	popup menuselect wumain weaponsunlimited/selecttype

	popup create wugrenades
	popup addline wugrenades "Select a Grenade"
	popup addline wugrenades "1. HE Grenade"
	popup addline wugrenades "2. Smoke Grenade"
	popup addline wugrenades "3. Flashbang"
	popup addline wugrenades "0. Quit"
	popup menuselect wugrenades weaponsunlimited/selectgrenade

	popup create wuprimary1
	popup addline wuprimary1 "Select a Weapon"
	popup addline wuprimary1 "1. AWP"
	popup addline wuprimary1 "2. Scout"
	popup addline wuprimary1 "3. Bullpup"
	popup addline wuprimary1 "4. MAC 10"
	popup addline wuprimary1 "5. TMP"
	popup addline wuprimary1 "6. MP5 Navy"
	popup addline wuprimary1 "7. UMP 45"
	popup addline wuprimary1 "8. P90"
	popup addline wuprimary1 "9. More"
	popup addline wuprimary1 "0. Quit"
	popup menuselect wuprimary1 weaponsunlimited/selectpri1

	popup create wuprimary2
	popup addline wuprimary2 "Select a Weapon"
	popup addline wuprimary2 "1. IDF Defender"
	popup addline wuprimary2 "2. Clarion 556"
	popup addline wuprimary2 "3. AK47"
	popup addline wuprimary2 "4. SG552"
	popup addline wuprimary2 "5. SG550"
	popup addline wuprimary2 "6. D3/AU-1"
	popup addline wuprimary2 "7. M249"
	popup addline wuprimary2 "8. Back"
	popup addline wuprimary2 "9. More"
	popup addline wuprimary2 "0. Quit"
	popup menuselect wuprimary2 weaponsunlimited/selectpri2

	popup create wuprimary3
	popup addline wuprimary3 "Select a Weapon"
	popup addline wuprimary3 "1. M4A1"
	popup addline wuprimary3 "2. 12 Guage"
	popup addline wuprimary3 "3. Auto 12 Guage"
	popup addline wuprimary3 "8. Back"
	popup addline wuprimary3 "0. Quit"
	popup menuselect wuprimary3 weaponsunlimited/selectpri3

	popup create wusecondary
	popup addline wusecondary "Select a Weapon"
	popup addline wusecondary "1. Glock"
	popup addline wusecondary "2. USP"
	popup addline wusecondary "3. P228"
	popup addline wusecondary "4. Deagle"
	popup addline wusecondary "5. Elites"
	popup addline wusecondary "6. 5-7"
	popup addline wusecondary "0. Quit"
	popup menuselect wusecondary weaponsunlimited/selectsec
}