//---------------------------------------------------------------------------------
// Show me the Money v 0.1
// by Don
// 4/28/2007
//
// Description:  This script will show you how much money the top "x" players on the
//               opposite team each have.  It is intended to be used with Mugmod so
//               you will know who is the richest target.
//
// Requirement:  ES v1.5
//
// Installation:  Copy this file to cstrike/addons/eventscripts/showmemoney/es_showmemoney.txt
//                and put this into your autoexec.cfg  es_load showmemoney
//
// Use:  Type "showmemoney" in either chat or console.
//
block load
{
//  Set this to the number of players to show
	es_set showtopnumber 5
	
//  Set this to the length of time to show the list
	es_set timetoshow 5
	
//--------------- no need to edit below this line ---------------------------------
	es_set showmoney_ver 0.1
	es_makepublic showmoney_ver
	es_set cashid 0
	es_set cashname 0
	es_set tempcash 0
	es_set richnewline 0
	es_set richtop 0
	es_set richteam 0
	es_xregclientcmd showmemoney showmemoney/showme
	es_xregsaycmd showmemoney showmemoney/showme
}

block showme
{
	es_getcmduserid cashid
	es_keygroupcreate riches
	es_getplayerteam richteam server_var(cashid)
	if (server_var(richteam) == 2) do
	{
		foreach player cashid #ct#alive "es_doblock showmemoney/getcash"
	}
	if (server_var(richteam) == 3) do
	{
		foreach player cashid #t#alive "es_doblock showmemoney/getcash"
	}
	keygroupsort riches cash des #numeric
	popup create richest
	es popup timeout richest view server_var(timetoshow)
	es popup addline richest "Richest Opponents"
	es_set richtop 0
	es_foreachkey cashid in riches "es_doblock showmemoney/makepopup"
	es_getcmduserid cashid
	es popup send richest server_var(cashid) 
	es_keygroupdelete riches
}

block getcash
{
	es playerget cash tempcash server_var(cashid)
	es_keycreate riches server_var(cashid)
	es_keysetvalue riches server_var(cashid) cash server_var(tempcash)
}

block makepopup
{
	if (server_var(richtop) < server_var(showtopnumber)) do
	{
		es_getplayername cashname server_var(cashid)
		es_keygetvalue tempcash riches server_var(cashid) cash
		es_format richnewline "%1   %2" server_var(cashname) server_var(tempcash)
		es popup addline richest server_var(richnewline)
		es_math richtop + 1
	}
}