//Regen Based on current health
//By: J3ff Hoogland
//Contanct Email: blue_starsoar@yahoo.com
//Home Page: www.dndsource.net
//Requested By: Dark Light Here: http://forums.mattie.info/cs/forums/viewtopic.php?t=18186
block load
{
	repeat create 10health "es_xdoblock rbch/10orless"
	repeat create 20health "es_xdoblock rbch/20orless"
	repeat create 40health "es_xdoblock rbch/40orless"
	repeat create 80health "es_xdoblock rbch/80orless"
	es_xset userid 0
	es_xset userhealth 0
}
block unload
{
	repeat stop 10health
	repeat stop 20health
	repeat stop 40health
	repeat stop 80health
	repeat delete 10health
	repeat delete 20health
	repeat delete 40health
	repeat delete 80health
}
event round_start
{
	es_xmsg #multi #green[Regeneration] #defaultPlayers will slowly regain lost health over time.
}
event es_map_start
{
	repeat start 10health 1
	repeat start 20health 2
	repeat start 40health 4
	repeat start 80health 10
}
block 10orless
{
	foreach player userid #alive "es_xdoblock rbch/10healcheck"
}
block 20orless
{
	foreach player userid #alive "es_xdoblock rbch/20healcheck"
}
block 40orless
{
	foreach player userid #alive "es_xdoblock rbch/40healcheck"
}
block 80orless
{
	foreach player userid #alive "es_xdoblock rbch/80healcheck"
}
block 10healcheck
{
	es playerget health userhealth server_var(userid)
	ifx parse("userhealth <= 10") do
	{
		es_xmath userhealth + 1
		es playerset health server_var(userid) server_var(userhealth)
	}
}
block 20healcheck
{
	es playerget health userhealth server_var(userid)
	ifx parse("userhealth <= 20 and userhealth > 10") do
	{
		es_xmath userhealth + 1
		es playerset health server_var(userid) server_var(userhealth)
	}
}
block 40healcheck
{
	es playerget health userhealth server_var(userid)
	ifx parse("userhealth <= 40 and userhealth > 20") do
	{
		es_xmath userhealth + 1
		es playerset health server_var(userid) server_var(userhealth)
	}
}
block 80healcheck
{
	es playerget health userhealth server_var(userid)
	ifx parse("userhealth <= 80 and userhealth > 40") do
	{
		es_xmath userhealth + 1
		es playerset health server_var(userid) server_var(userhealth)
	}
}