block load 
{
 es_xset var_record 0
 es_xset var_roundended 0
 es_xset var_donePcount 1
 es_xset var_adminfirst 0
 es_xset var_admincheck 0
 es_xset var_userid 0
 es_xset var_steamid 0
 es_xset var_username 0
 es_xset var_userexists 0
 es_xset var_adminexists 0
 es_xset var_score_t 0
 es_xset var_score_ct 0
 es_xset var_score_t_al 0
 es_xset var_score_ct_al 0
 es_xset var_donestatus 0
 es_xset var_temp 0
 es_xset var_firstspawn 0
 es_xset var_gavebomb 0
 es_xset var_afterload 0  
 
 es_keygroupdelete adminlr
 es_keygroupload adminlr |loadlr
 es_keygroupdelete Score
 es_keygroupload Score |loadlr
 es_keygroupdelete Pdata1
 es_keygroupload Pdata1 |loadlr
 es_keygroupdelete Pdata2
 es_keygroupload Pdata2 |loadlr
}

//                 -------------PLAYER SPAWN --------------   
event player_spawn
{
  //                      Checking For Score
  
  
  if (server_var(var_record) == 1 ) do
  { 
    es score get var_score_t #t
    es score get var_score_ct #ct      
  }   
  if (server_var(var_score_t) == 0 )do
  {
    if (server_var(var_score_ct) == 0 )do
    {     
    //               If Score is CT:0 & T:0 Then - var_record = 0 
      if (server_var(var_record) == 1 ) do
      {    
      
      es_xset var_record 0
      es_xmsg #multi #lightgreenLoadLR:#green Warning!!  Recording is now OFF!
      } 
    }
  }

 
 //                   Counting Alive Players
  if (server_var(var_donePcount) equalto 0 )do
  {
    es_xset var_playerscount 0
    foreach player b #human#alive "es_math var_playerscount + 1"
    es_xset var_donePcount 1  
  }
 //                    Saving Players Info 
  if (server_var(var_record) == 1)do
  {
    if (event_var(es_steamid) != "bot") do
    {
       if (server_var(var_roundended) == 1 ) do
       {
         if(server_var(var_playerscount) > server_var(var_donestatus) ) do
         {
  //                       CT & T Score
           if ( server_var(var_donestatus) == 0 ) do   
           {                             
              es score get var_temp #t    
              es_keysetvalue Score Tscore T server_var(var_temp)
              es score get var_temp #ct    
              es_keysetvalue Score CTscore CT server_var(var_temp) 
              es_keygroupsave Score |loadlr
           }
           es_exists var_userexists key Pdata1 event_var(es_steamid)
           if (server_var(var_userexists) == 0 ) do
           {
              es_keycreate Pdata1 event_var(es_steamid)
           } 
           es_exists var_userexists key Pdata2 event_var(es_steamid)
           if (server_var(var_userexists) == 0 ) do
           {
              es_keycreate Pdata2 event_var(es_steamid)
              es_set var_userexists 1
           } 
             
           if (server_var(var_userexists) == 1 ) do
           {
              es_set var_steamid event_var(es_steamid)          
              es_set var_userid event_var(userid)
              es_set var_userteam event_var(es_userteam)
              es_keysetvalue Pdata1 event_var(es_steamid) rounds_away 0
              es_xdoblock loadlr/saveinfo   
           }
          es_math var_donestatus + 1
        } 
      }  
    }
  }
//                     Done Saving Status

 //                    Loading Players Info 
  if (server_var(var_load) == 1)do
  { 
    if (event_var(es_steamid) != "bot") do
    {        
         if(server_var(var_playerscount) > server_var(var_donestatus) ) do
         {
 
           es_exists var_userexists key Pdata1 event_var(es_steamid)
           if (server_var(var_userexists) == 1 ) do
           {
            
              es_set var_steamid event_var(es_steamid)          
              es_set var_userid event_var(userid)
              es_doblock loadlr/loadinfo1
              if (server_var(var_gavebomb) == 0 ) do
              {
              es_set var_userteam event_var(es_userteam)
              }
           } 
           es_exists var_userexists key Pdata2 event_var(es_steamid)
           if (server_var(var_userexists) == 1 ) do
           {
              es_set var_steamid event_var(es_steamid)          
              es_set var_userid event_var(userid)
              es_doblock loadlr/loadinfo2
           }   
           if (server_var(var_userexists) == 0 ) do
           {
  
           }
          
          es_math var_donestatus + 1
        } 
      }  
    }
  if (server_var(var_playerscount) == server_var(var_donestatus)) do
  {
    if (server_var(var_load) == 1 ) do
    {
      es_keygetvalue var_score_ct Score CTscore CT
      es_keygetvalue var_score_t Score Tscore T
  
      es_format var_temp "(CT): %1, (T): %2"server_var(var_score_ct) server_var(var_score_t)
      es_xdelayed 2 es_xmsg #multi #lightgreenLoadLR:#green Loading Done!
      es_xdelayed 3.5 es_xmsg #green gl hf...
      es_xset var_afterload 1
      es_keysetvalue Score afterload_score T server_var(var_score_t)
      es_keysetvalue Score afterload_score CT server_var(var_score_ct)
      es score set #ct server_var(var_score_ct)
      es score set #t server_var(var_score_t)
      es_keygroupsave Score |loadlr
      es_xset var_load 0
    }
    es_xset var_roundended 0
    es_math var_donestatus + 1      
  }
  if (server_var(var_firstspawn) == 0 ) do
  {
   es_xset var_firstspawn 1 
  } 

}

//                ------------- ROUND START ----------------- 
event round_start
{
  if(server_var(var_record) == 1) do
  {                                        

    foreach player var #human "es_math var_temp + 1" 
    if(server_var(var_temp) == 0 ) do
    {
     es_xset var_record 0
     es_xset var_roundended 0
     es_xset var_afterload 0
    } 
  }  
  if(server_var(var_afterload) == 1) do 
  {
    es score get var_score_ct #ct
    es score get var_score_t #t  
    es_math var_score_ct + server_var(var_score_t)    
    if (server_var(var_score_ct) == 0 ) do
    {
      es_xset var_afterload 0 
    }
  }  
}
//                ------------- ROUND END -----------------
event round_end
{
  if (event_var(reason) == 10) do
  {
    es_xset var_record 0
    es_xset var_roundended 0
    es_xset var_afterload 0
    es_xmsg #multi #lightgreenLoadLR:#green Warning!!  Recording is now OFF!
  } 
  if(server_var(var_record) == 1) do
  {                                                  
    es_xset var_donePcount 0
    es_xset var_donestatus 0
    es_xset va_firstspawn 0
    es_xset var_roundended 1
    foreach player var_userid #human "es_xdoblock loadlr/set_died_1"
    foreach player var_userid #human#alive "es_xdoblock loadlr/set_died_0"
    es_foreachkey var_steamid in Pdata1 "es_doblock loadlr/deleteaway"
    
    es_xset var_temp 0
    foreach player var #human "es_math var_temp + 1" 
    if(server_var(var_temp) == 0 ) do
    {
     es_xset var_record 0
     es_xset var_roundended 0
     es_xset var_afterload 0
    } 
  }  

  if(server_var(var_afterload) == 1) do
  {
   es score get var_score_ct #ct
   es score get var_score_t #t 
   es_keygetvalue var_score_t_al Score afterload_score T
   es_keygetvalue var_score_ct_al Score afterload_score CT 

   es_math var_score_ct_al + server_var(var_score_ct)
   es_math var_score_t_al + server_var(var_score_t)

   es score set #ct server_var(var_score_ct_al)
   es score set #t server_var(var_score_t_al)
   es_keygroupsave Score |loadlr
  }  

}
//                ------------- PLAYER DEATH -----------------
event player_death 
{
    if (server_var(var_record) == 1 )do
  {  
   es_keysetvalue Pdata1 event_var(es_steamid) Pdied  1
   es_set var_temp event_var(es_userdeaths)
   es_math var_temp + 1
   es_keysetvalue Pdata1 event_var(es_steamid) Pdeaths_tmp server_var(var_temp) 
  }
}
//                ------------- PLAYER SAY -----------------
event player_say
{
  // Admin Setup   
  if ( event_var(text) == "@adminme" ) do
  {
    es_exists var_adminfirst key adminlr adminlrfirst
    if (server_var(var_adminfirst) == 0 ) do
    {
      es_keygroupcreate adminlr
      es_keycreate adminlr event_var(es_steamid)
      es_keysetvalue adminlr event_var(es_steamid) adminlr event_var(es_username)
      es_keycreate adminlr adminlrfirst
      es_keysetvalue adminlr adminlrfirst event_var(es_steamid) event_var(es_username)
      es_tell event_var(userid) #green You're now an admin!
      es_keygroupsave adminlr |loadlr
    }
    else do
    {
      es_msg #multi #lightgreenLoadLR:#green Theres already a First Admin.
    }
  }

  if ( "@" in event_var(text) ) do
  {
    // Checking if SreamID is admin on admin_db
    es_exists var_admincheck key adminlr event_var(es_steamid)
    if (server_var(var_admincheck) == 0 ) do
    {
      es_exists var_admincheck keyvalue adminlr adminlrfirst event_var(es_steamid)
    }
    if (server_var(var_admincheck) == 1 ) do
    {
      es_set var_txt event_var(text)
      es_set var_name event_var(es_username)
      es_xdoblock loadlr/block_commands
    }
  }   
}
//                ------------- SAY COMMANDS -----------------
block block_commands
{
  if ( "@addadmin" in event_var(text) )do
  {
    es_set txt server_var(var_txt)
    es_string txt section 0 9
    if ( server_var(txt) == "@addadmin" )do
    {
      es_xdoblock loadlr/addadmin
    }
  }
  if ( "@removeadmin" in event_var(text) )do
  {
    es_set txt server_var(var_txt)
    es_string txt section 0 12
    if ( server_var(txt) == "@removeadmin" )do
    {
      es_xdoblock loadlr/removeadmin
    }
  }
  // Admins List "!adminlist"
  if (server_var(var_txt) equalto "@adminlist") do
  {
    es_xmsg #green LoadLR Admins Are:
    es_foreachkey txt2 in adminlr "es_xdoblock loadlr/adminlist"
  }


  if(server_var(var_txt) equalto "@loadlr") do
  {
    es_xmsg #green LoadLR Ver0.8 by Lazylion.
    es_xdelayed 1 es_xmsg #multi #lightgreenLoadLR:#default Loading...
    es_xset var_donePcount 0
    es_xset var_donestatus 0
    es_xset var_gavebomb 0
  //  es_set var_firstspawn 0
    es_xset var_load 1   
    es_delayed 1.5 mp_restartgame 1
  }
//                ------------- Turning Record On -----------------
  if(server_var(var_txt) equalto "@record") do
  {
    if (server_var(var_record) == 0 ) do
    {
      es_xset var_playerscount 2
      es_xset var_donePcount 1 
      es_xset var_record 1      
      es_keygroupcreate Pdata1  
      es_keygroupcreate Pdata2
      es_keygroupcreate Score 
      es_keycreate Score Tscore
      es_keycreate Score CTscore
      es_keycreate Score afterload_score
      es_msg #multi #lightgreenLoadLR:#green Recording Is Now On! 
      es_msg #multi #lightgreenLoadLR:#default Type @LoadLR to load last rounds status.
      es_msg #multi #lightgreenLoadLR:#default Type @stop to stop recording.
    }
    else do
    {
      es_xmsg #multi #lightgreenLoadLR:#green Recording is Already On!
    }

  }
  if(server_var(var_txt) equalto "@stop") do
  {
    if (server_var(var_record) == 0 ) do
    {
      es_xmsg #multi #lightgreenLoadLR:#green Recording is Already Off!      
    }
    else do
    {
      es_xset var_record 0   
      es_msg #multi #lightgreenLoadLR:#green Recoring Is Now Off!
    }
  }
  if(event_var(text) equalto "@help") do
  {
    es_xmsg #green LoadLR Ver0.8 by Lazylion 
    es_xmsg #green Commands Are:    
    es_xmsg #green @AddAdmin, @RemoveAdmin, @AdminList 
    es_xmsg #green @record, @LoadLR, @stop
  }

}  
block addadmin
{
  es_set var_addedsteamid 0
  es_set txt2 server_var(var_txt)
  es_xset txtlength 0
  es_strlen txtlength server_var(var_txt)
  es_string txt2 section 10 server_var(txtlength)
  es_getuserid var_userid server_var(txt2)
  es est_getname var_username server_var(var_userid)
  es est_getsteam var_steamid server_var(var_userid)
  es_exists var_userexists userid server_var(var_userid)
  if (server_var( var_userexists) == 0 )do
  {

    if ( "STEAM_" in server_var(txt2) ) do
    {
      es_exists var_adminexists key adminlr server_var(txt2)
      if ( server_var(var_adminexists) == 0 ) do
      {
        es_keycreate adminlr server_var(txt2)
        es_keysetvalue adminlr server_var(txt2) 1 noname
        es_msg #multi #lightgreenLoadLR:#green Added server_var(txt2) to Admin list.
        es_keygroupsave adminlr |loadlr
        es_set var_addedsteamid 1
      }
      else do
      {
        es_msg #multi #lightgreenLoadLR:#green server_var(txt2) Is already an admin.
        es_set var_addedsteamid 1
      }

    }
  }
  else do
  {

    if ( "STEAM_" in server_var(var_username) ) then es_set var_userexists 0

    if ( server_var(var_userexists) == 1 ) do
    {
      es_exists var_adminexists key adminlr server_var(var_steamid)
      if ( server_var(var_adminexists) == 1 ) do
      {
        es_msg #multi #lightgreenLoadLR:#green server_var(var_steamid) Is already an admin.
      }
      else do
      {
        es_keycreate adminlr server_var(var_steamid)
        es_keysetvalue adminlr server_var(var_steamid) adminlr server_var(var_username)
        es_msg #multi #lightgreenLoadLR:#green Added server_var(var_username) - server_var(var_steamid) to Admin list.
        es_keygroupsave adminlr |loadlr
      }
    }

  }
  if ( server_var(var_userexists) == 0 ) do
  {
    if (server_var(var_addedsteamid) == 0 ) do
    {
      es_msg #multi #lightgreenLoadLR:#green Could Not Find User In The Server
    }
  }
}
block removeadmin
{
  es_set txt2 server_var(var_txt)
  es_xset txtlength 0
  es_strlen txtlength server_var(var_txt)
  es_string txt2 section 13 server_var(txtlength)
  es_exists var_userexists key adminlr server_var(txt2)
  if (server_var( var_userexists) == 1 )do
  {

    es_keydelete adminlr server_var(txt2)
    es_keygroupsave adminlr |loadlr
    es_msg #multi #lightgreenLoadLR:#green Admin server_var(txt2) Removed.

  }

  else do
  {
    es_msg #multi #lightgreenLoadLR:#green No such SteamID in the database.
  }
}
block adminlist
{
  if ( "STEAM_" in server_var(txt2) )do
  {
    es_keygetvalue var_username adminlr server_var(txt2) adminlr
    es_msg #green server_var(var_username) - server_var(txt2)
  }
}
block set_died_1
{
es est_getsteam var_steamid server_var(var_userid)
es_keysetvalue Pdata1 server_var(var_steamid) Pdied 1  
}
block set_died_0
{
es est_getsteam var_steamid server_var(var_userid)
es_keysetvalue Pdata1 server_var(var_steamid) Pdied 0  
}
//                ------------- SAVE STATS -----------------
block saveinfo
{
//                ************  Pdata1 *************
                 
                    //-----Players score-----
  es score get var_temp server_var(var_userid)
  es_keysetvalue Pdata1 server_var(var_steamid) Pscore server_var(var_temp)
                  // -------Players Deaths------
  es_keygetvalue var_temp Pdata1 server_var(var_steamid) Pdied
  if (server_var(var_temp) == 1 ) do
  {
    es_keygetvalue var_temp Pdata1 server_var(var_steamid) Pdeaths_tmp
    es_keysetvalue Pdata1 server_var(var_steamid) Pdeaths server_var(var_temp)
  }
                   // -----------------Money------------------ 
  es playerget cash var_cash server_var(var_userid)
  es_keysetvalue Pdata1 server_var(var_steamid) Cash server_var(var_cash)

                 
//               ************  Pdata2 *************   
  es_keygetvalue var_temp Pdata1 server_var(var_steamid) Pdied
  if (server_var(var_temp) == 0 ) do
  {             
                    // ---------------Armor----------- 
                    
    es playerget armor var_temp server_var(var_userid)                                
    es_keysetvalue Pdata2 server_var(var_steamid) armor server_var(var_temp)
    es_getplayerprop var_temp server_var(var_userid) CCSPlayer.m_bHasHelmet
    es_keysetvalue Pdata2 server_var(var_steamid) armor_type server_var(var_temp)
  
  //           ----------------Weapons----------------
  //                              Flashbang
    es playerget fb var_temp server_var(var_userid)
    es_keysetvalue Pdata2 server_var(var_steamid) flashbang server_var(var_temp)
  //                              Handgrenade
    es playerget he var_temp server_var(var_userid)
    es_keysetvalue Pdata2 server_var(var_steamid) hegrenade server_var(var_temp)
  //                             Smokegrenade
    es playerget sg var_temp server_var(var_userid)
    es_keysetvalue Pdata2 server_var(var_steamid) smokegrenade server_var(var_temp)                              
  //                           Secondery Weapon
    es playerget secondary var_temp server_var(var_userid)
    es_keysetvalue Pdata2 server_var(var_steamid) pistol server_var(var_temp)
  //                            Primary Weapon
    es playerget primary var_temp server_var(var_userid)
    es_keysetvalue Pdata2 server_var(var_steamid) weapon server_var(var_temp)
  //                                Kit
    if ( server_var(var_userteam) == 2 )
    {
      es playerget defuser var_temp server_var(var_userid)
      es_keysetvalue Pdata2 server_var(var_steamid) defuser server_var(var_temp)   
    }
    else do
    {
      es_keysetvalue Pdata2 server_var(var_steamid) defuser 0      
    }
 //                             NightVision  
    es_xset p_prop 0 
    es_getplayerprop p_prop server_var(var_userid) "CCSPlayer.m_bHasNightVision"
    es_set p_len 0
    es_strlen p_len server_var(p_prop)
    es_set p_len2 server_var(p_len)
    es_math p_len2 - 1
    es_string p_prop section server_var(p_len2) server_var(p_len)
    es_math p_prop / 2
    es_set t_var server_var(p_prop)
    es_math t_var int
    es_math p_prop - server_var(t_var)
    es_math p_prop * 2
    es_set hasnv server_var(p_prop)
    es_keysetvalue Pdata2 server_var(var_steamid) nightvision server_var(hasnv)
  } 
  //   If Player Died Last Round his Pdata2 is erased 
  else do
  {
  es_keydelete Pdata2 server_var(var_steamid)   
  }
  //                    Saving Key Group    
    
  es_keygroupsave Pdata1 |loadlr
  es_keygroupsave Pdata2 |loadlr
}
block loadinfo1
{
          // Give Cash
          es_keygetvalue var_temp Pdata1 server_var(var_steamid) cash
          es playerset cash server_var(var_userid) server_var(var_temp)   
         // Set Players Score 
          es_keygetvalue var_temp Pdata1 server_var(var_steamid) Pscore 
          es est_KillSet server_var(var_userid) server_var(var_temp) 
          // Set Players Deaths
          es_keygetvalue var_temp Pdata1 server_var(var_steamid) Pdeaths
          es est_DeathSet server_var(var_userid) server_var(var_temp)
          if (server_var(var_gavebomb) == 0 ) do
          {
            if (server_var(var_userteam) == 1 ) do
            {
              es_give server_var(var_userid) weapon_c4
              es_xset var_gavebomb 1
            } 
          }
}          
block loadinfo2
{
          // Strip Player of Weapons
          es est_StripPlayer server_var(var_userid) 1
          // Give Knife
          es_give server_var(var_userid) weapon_knife
          // Give Weapon
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) weapon
          es_give server_var(var_userid) server_var(var_temp)
          // Give Pistol
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) pistol
          es_give server_var(var_userid) server_var(var_temp) 
          // Give Smoke

          es_keygetvalue var_temp Pdata2 server_var(var_steamid) smokegrenade
          if ( server_var(var_temp) == 1 ) do
          {
          es_give server_var(var_userid) weapon_smokegrenade
          }
          // Give Flash
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) flashbang
          if ( server_var(var_temp) == 1 ) do
          {
            es_give server_var(var_userid) weapon_flashbang
          }
          if ( server_var(var_temp) == 2 ) do
          {
            es_give server_var(var_userid) weapon_flashbang
            es_give server_var(var_userid) weapon_flashbang
          }
          // Give Nade
          
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) hegrenade
          if ( server_var(var_temp) == 1 ) do
          {
            es_give server_var(var_userid) weapon_hegrenade 
          }
          // Give Armor
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) armor_type
          if  ( server_var(var_temp) == 1 ) do
          {  
            es_give server_var(var_userid) item_assaultsuit
          }
          else do
          {
            es_give server_var(var_userid) item_kevlar
          }
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) armor
          if (server_var(var_temp) < 100 ) do
          {
          es playerset armor server_var(var_userid) server_var(var_temp)
          }
           //Give Kit
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) defuser
          if ( server_var(var_temp) == 1 ) do
          {
            es_give server_var(var_userid) item_defuser
          }
          //Give NightVision
          es_keygetvalue var_temp Pdata2 server_var(var_steamid) nightvision
          if ( server_var(var_temp) == 1 ) do
          {
            es_give server_var(var_userid) item_nvgs
          }
  
}
block deleteaway
{   
es_getuserid var_userid server_var(var_steamid)
es_exists var_temp server_var(var_userid)
if (server_var(var_temp) == 0) do
{
  es_keygetvalue var_temp Pdata1 server_var(var_steamid) rounds_away
  if (server_var(var_temp) > 1 ) do
  {
    es_keydelete Pdata1 server_var(var_steamid)
    es_keydelete Pdata2 server_var(var_steamid)
  }
  else do
  {
    es_math var_temp + 1
    es_keysetvalue Pdata1 server_var(var_steamid) rounds_away server_var(var_temp)
  }
} 

}