//// Script: FDGSpawn 1.3
//// Author: Fishy, initial development: Sleepingpills
//// Requires: EventScripts 1.5 with Popups loaded.
//// Übersetzt durch Robert alias robiroym alias Rovbiro
//// After loading this script clients MUST RECONNECT to receive credits, I suggest changing the level to accomplish this
////---------------------------------------------------------------------
//// Übersetzt durch Robert alias robiroym alias Rovbiro

// Das Script einstellen:
block config
{
	// Die maximale Anzahl an Credits, die ein Spieler an Credits haben kann.
	es_xsetinfo credits_max 14
	
	// Die Anzahl an Credits die man bein Connecten bekommt
	// Du musst credits_max ändern.
	es_xsetinfo credits_connect 4
	
	// Der Client bekommt die Anzahl an Credits beim Spawnen
	es_xsetinfo credits_spawn 5
	
	// Wenn Du jemanden tötest bekommst Du diese Anzahl an Credits
	es_xsetinfo credits_kill 1
	
	// Die Anzahl der Sekunden, nach dem Connecten die Das Plugin seine Infos anzeigt
	es_xsetinfo credits_helpdelay 10
}

// BITTE ÄNDERE NICHTS NACH DIESER LINIE-----
block load 
{
    es_doblock fdgspawn/config
    if (server_var(credits_connect) greaterthan server_var(credits_max)) do
   {
   		es_xsetinfo credits_connect server_var(credits_max)
   }
	  es_keygroupcreate s_uses 
    es_doblock fdgspawn/propmenupopup 
    es_msg FDG Spawner (1.3) was (re)loaded. Please reconnect or change the map.
} 

block unload
{
	es_keygroupdelete s_uses
	es_msg FDG Spawner (1.3) ist ausgestellt. Du kannst nicht mehr !propmenu benutzen
}

event player_spawn
{ 
   es_xsetinfo s_stemp 0 
   es_keygetvalue s_stemp s_uses event_var(userid) uses
   es_math s_stemp + server_var(credits_spawn)
   if (server_var(s_stemp) greaterthan server_var(credits_max)) do
   {
   		es_keysetvalue s_uses event_var(userid) uses server_var(credits_max)
   		es_tell event_var(userid) #green Deine Credits: server_var(credits_max) (Maximum Allowed)
   }
   else do
   {
   		es_keysetvalue s_uses event_var(userid) uses server_var(s_stemp)
   		es_tell event_var(userid) #green Deine Credits: server_var(s_stemp) (+ server_var(credits_spawn))
   }
} 

event player_activate
{
   es_delayed server_var(credits_helpdelay) es_tell event_var(userid) #lightgreen Schreibe in den Chat !propmenu rein um
   es_delayed server_var(credits_helpdelay) es_tell event_var(userid) #lightgreen Gegenstände zu spawnen.
   es_keydelete s_uses event_var(userid) 
   es_keycreate s_uses event_var(userid) 
   es_keysetvalue s_uses event_var(userid) uses server_var(credits_connect)
}

event player_disconnect 
{ 
   es_keydelete s_uses event_var(userid) 
} 

event player_death
{
	es_xsetinfo s_dtemp 0 
	es_keygetvalue s_dtemp s_uses event_var(attacker) uses
	es_math s_dtemp + server_var(credits_kill)
	 if (server_var(s_dtemp) greaterthan server_var(credits_max)) do
   {
   		es_keysetvalue s_uses event_var(attacker) uses server_var(credits_max)
   		es_tell event_var(attacker) #green Deine Credits: server_var(credits_max) (Maximum Allowed)
   }
   else do
   {
   		es_keysetvalue s_uses event_var(attacker) uses server_var(s_dtemp)
   		es_tell event_var(attacker) #green Deine Credits: server_var(s_dtemp) (+ server_var(credits_kill))
   }
}

//========================================= 
//========================================= 
//========================================= 
//========================================= 
event player_say 
{ 
        if (event_var(text) equalto !propmenu) do 
        { 
                if (event_var(es_userdead) == 0) do 
                { 
                        es popup send propmenu1 event_var(userid)
                        es_xsetinfo s_temp 0
						es_keygetvalue s_temp s_uses event_var(userid) uses
                        es_tell event_var(userid) #green Deine Credits: server_var(s_temp) 
                } 
                else do 
                { 
                        es_tell event_var(userid) Tote Spieler koennen das Propmenu nicht nutzen. 
                } 
        }
        
        if (event_var(text) equalto !propinfo) do 
        { 
              es_tell event_var(userid) #green Anfangs Credits: server_var(credits_connect)
              es_tell event_var(userid) #green Spawn Credits: server_var(credits_spawn)
              es_tell event_var(userid) #green Kill Credits: server_var(credits_kill)
              es_tell event_var(userid) #green Maximale Credits: server_var(credits_max)
              es_tell event_var(userid) #green Script Version: 1.3
        }
        
        
} 
//========================================= 
//========================================= 
//========================================= 
//========================================= 
block propmenupopup 
{ 
        popup create propmenu1 
        popup addline propmenu1 "==============================" 
        popup addline propmenu1 "| Prop-Gegenstaende spawnen |"
        popup addline propmenu1 "==============================" 
        popup addline propmenu1 "->1. Aktenschrank - 2 Credits" 
        popup addline propmenu1 "->2. Atommuell-Fass - 2 Credits" 
        popup addline propmenu1 "->3. Waschmaschiene - 3 Credits" 
        popup addline propmenu1 "->0. Exit" 
        popup submenu propmenu1 1 propmenu1 
        popup submenu propmenu1 2 propmenu1 
        popup submenu propmenu1 3 propmenu1 
        popup select propmenu1 1 fdgspawn/filecabmen 
        popup select propmenu1 2 fdgspawn/barrelmen 
	popup select propmenu1 3 fdgspawn/dryermen 

        //========================================= 
        //========================================= 
        //========================================= 
        //========================================= 
} 

//========================================= 
block filecabmen 
{
	es_xsetinfo s_temp 0 
	es_keygetvalue s_temp s_uses server_var(_popup_userid) uses
	if (server_var(s_temp) greaterthan 1) do 
	{ 
        	es_prop_physics_create server_var(_popup_userid) props/cs_office/file_cabinet1.mdl 
		es_math s_temp - 2
		es_keysetvalue s_uses server_var(_popup_userid) uses server_var(s_temp)
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (-2)
	}
	else do
	{
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (insufficient funds!)
	}
}
//========================================= 
block barrelmen 
{
	es_xsetinfo s_temp 0 
	es_keygetvalue s_temp s_uses server_var(_popup_userid) uses
	if (server_var(s_temp) greaterthan 1) do 
	{ 
        	es_prop_physics_create server_var(_popup_userid) props/de_train/Barrel.mdl  
		es_math s_temp - 2
		es_keysetvalue s_uses server_var(_popup_userid) uses server_var(s_temp)
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (-2)
	}
	else do
	{
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (insufficient funds!)
	}
}
//========================================= 
block dryermen 
{
	es_xsetinfo s_temp 0 
	es_keygetvalue s_temp s_uses server_var(_popup_userid) uses
	if (server_var(s_temp) greaterthan 2) do 
	{ 
        	es_prop_physics_create server_var(_popup_userid) props/cs_militia/dryer.mdl 
		es_math s_temp - 3
		es_keysetvalue s_uses server_var(_popup_userid) uses server_var(s_temp)
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (-3)
	}
	else do
	{
		es_tell server_var(_popup_userid) #green Deine Credits: server_var(s_temp) (insufficient funds!)
	}
}