block load
{
  es_xsetinfo dm_endround_v "1.61"

  es_xsetinfo dm_temp 0
  es_xsetinfo dm_roundon 0
  es_xmakepublic dm_endround_v
  es_xexists dm_temp variable dm_endround
  if (server_var(dm_temp) == 0) do
  {
    es_xsetinfo dm_endround 1
    es_xsetinfo dm_endround_effect 1
  }
  es_xexists dm_temp command dmer
  if (server_var(dm_temp) == 0) then es_xregcmd dmer dmendround/endround "Ends the current round [DM EndRound]"
  es_dbgmsg 0 DM EndRound server_var(dm_endround_v) has been loaded!
  es_dbgmsg 0 dm_endround = server_var(dm_endround) [0=disabled, 1=enabled]
  
  es_xsetinfo dm_roundtime 0
  es_xsetinfo dm_endround_count 0
}

event es_map_start
{
  es_xsetinfo dm_endround_count 0
}

event round_start
{
  es_xsetinfo dm_roundon 1
}

event round_end
{
  es_xsetinfo dm_roundon 0
}

event round_freeze_end
{
  es_xmath dm_endround_count + 1
  es_xdelayed 30 es_xdoblock dmendround/tracking
}

block tracking
{
  if (server_var(dm_roundtime) > 0) do
  {
    es_setinfo eg_time server_var(dm_roundtime)
  }
  else do
  {
    es_setinfo eg_time server_var(mp_roundtime)
  }
  es_xmath eg_time * 60
  es_xmath eg_time - 30
  if (server_var(eg_time) <= 0) do
  {
    es_xdoblock dmendround/tendround
  }
  else do
  {
    es_delayed server_var(eg_time) es_xdoblock dmendround/tendround
  }
}

block endround
{
  refcount increment sv_cheats 1
  endround
  refcount decrement sv_cheats 1
}

block tendround
{
  es_xmath dm_endround_count - 1
  if (server_var(dm_endround_count) <= 0) do
  {
    es_xsetinfo dm_endround_count 0
    if (server_var(dm_endround) != 0) do
    {
      if (server_var(dm_roundon) == 1) do
      {
        es_xdoblock dmendround/endround_effect
      }
    }
  }
}

block endround_effect
{
  if (server_var(dm_endround_effect) == 1) do
  {
    foreach player dm_temp #all "es_xdoblock dmendround/player_effect"
    es_xdelayed 2 es_xdoblock dmendround/endround
    es_xcentermsg Round Draw!
  }
  else do
  {
    es_xdoblock dmendround/endround
  }
}

block player_effect
{
  es_cexec server_var(dm_temp) "play radio/rounddraw.wav"
  es_setplayerprop server_var(dm_temp) "CCSPlayer.m_iPlayerState" 1
}