// es_actions
// Author: Lumpi@Work
// Version: 1.1 | Build Date: 11/15/08
// Description: Enhanced options for triggered events (for EventScripts)

/////////////////////////
// SCRIPT CONFIGURATION
/////////////////////////

block actions_conf
{
	// Turn actions on (1) or off (0)
	es_xsetinfo ac_tell_bomb_defused 1
	es_xsetinfo ac_tell_bomb_planted 1
	es_xsetinfo ac_tell_hostage_rescued 1
	
	// Give a player extra money for defusing the bomb
	// Min. 0 - max. 16000 - def. 1000
	es_xsetinfo ac_add_money_bomb_defused 1000

	// Give a player extra money for planting the bomb
	// Min. 0 - max. 16000 - def. 1000
	es_xsetinfo ac_add_money_bomb_planted 1000

	// Give a player extra money for rescuing a hostage
	// Min. 0 - max. 16000 - def. 500
	es_xsetinfo ac_add_money_hostage_rescued 500

	// Set the script language
	// Available languages: english, german
	es_xsetinfo ac_script_language english

}

/////////////////////////
// END OF CONFIG
/////////////////////////

block load
{

	es_xsetinfo ac_ver 1.1
	es_makepublic ac_ver

	es_xdoblock actions/actions_conf

	es_xmsg #multi #green[Actions]#default: #lightgreenLoaded - Made by [BuH]Lump1

}

block unload
{

	es_xmsg #multi #green[Actions]#default: #lightgreenUnloaded

}

event bomb_defused
{
	if (server_var(ac_tell_bomb_defused) equalto 1) do
	{	
		if (server_var(ac_add_money_bomb_defused) > 0) do
		{
			es playerset cashadd event_var(userid) server_var(ac_add_money_bomb_defused)
			if (server_var(ac_script_language) equalto english) do
			{	
				es_tell event_var(userid) #multi #greenYou got #lightgreen$ server_var(ac_add_money_bomb_defused)#green for defusing the bomb!
			}
			else do
			{
				es_tell event_var(userid) #multi #greenFür das Entschärfen der Bombe hast du #lightgreen$ server_var(ac_add_money_bomb_defused)#green bekommen!	
			}
		}
		if (server_var(ac_script_language) equalto english) do
		{
			es_msg #multi #green event_var(es_username) #defaultdefused the bomb!
		}
		else do
		{
			es_msg #multi #green event_var(es_username) #defaulthat die Bombe entschärft!
		}
	}
}

event bomb_planted
{
	if (server_var(ac_tell_bomb_planted) equalto 1) do
	{	
		if (server_var(ac_add_money_bomb_planted) > 0) do
		{
			es playerset cashadd event_var(userid) server_var(ac_add_money_bomb_planted)
			if (server_var(ac_script_language) equalto english) do
			{
				es_tell event_var(userid) #multi #greenYou got #lightgreen$ server_var(ac_add_money_bomb_planted)#green for planting the bomb!
			}
			else do
			{
				es_tell event_var(userid) #multi #greenFür das Legen der Bombe hast du #lightgreen$ server_var(ac_add_money_bomb_planted)#green bekommen!		
			}
		}
		if (server_var(ac_script_language) equalto english) do
		{
			es_msg #multi #green event_var(es_username) #defaultplanted the bomb!
		}
		else do
		{
			es_msg #multi #green event_var(es_username) #defaulthat die Bombe gelegt!
		}
	}
}

event hostage_rescued
{
	if (server_var(ac_tell_hostage_rescued) equalto 1) do
	{
		if (server_var(ac_add_money_hostage_rescued) > 0) do
		{
			es playerset cashadd event_var(userid) server_var(ac_add_money_hostage_rescued)
			if (server_var(ac_script_language) equalto english) do
			{
				es_tell event_var(userid) #multi #greenYou got #lightgreen$ server_var(ac_add_money_hostage_rescued)#green for rescuing a hostage!
			}
			else do
			{
				es_tell event_var(userid) #multi #greenFür die Rettung der Geisel hast du #lightgreen$ server_var(ac_add_money_hostage_rescued)#green bekommen!
			}
		}

		if (server_var(ac_script_language) equalto english) do
		{
			es_msg #multi #green event_var(es_username) #defaultrescued a hostage!
		}
		else do
		{
			es_msg #multi #green event_var(es_username) #defaulthat eine Geisel gerettet!
		}
	}
}